defs.rkt

#lang racket/base
(require scribble/base)
(require scribble/decode)
(require scribble/manual)
(require racket/class)
(require racket/draw)
(require racket/system)
(require racket/port)
(require racket/vector)
(require racket/file)

(provide (all-defined-out))

; Check to see if we are building Apt or CloudLab documentation
(define tb-mode 
  (if (vector-member "clab" (current-command-line-arguments))
    'clab
    'apt))

(define (apt?) (if (equal? tb-mode 'apt) #t #f))
(define (clab?)  (if (equal? tb-mode 'clab) #t #f))

; Check to see if we are building for web or PDF; there is probably some
; nicer way to do this by inspecting the scribble/run state directly, but
; I haven't figured it out
(define doc-mode
    (if (vector-member "pdf" (current-command-line-arguments))
      'pdf
      'html))

(define (apt-vs-clab #:apt [apt-version (list)] #:clab [clab-version (list)])
  (if (apt?)
    apt-version
    clab-version))

(define (apt-vs-clab* #:apt [apt-version ""] #:clab [clab-version ""])
  (decode-flow (list (if (apt?)
                          apt-version
                          clab-version))))

(define (apt-only . stuff)
  (apt-vs-clab #:apt stuff))

(define (clab-only . stuff)
  (apt-vs-clab #:clab stuff))

(define apt-base-url
  (if (clab?)
    "https://www.cloudlab.us/"
    "https://www.aptlab.net/"))

(define apt-doc-url
  (if (clab?)
    "http://docs.cloudlab.us/"
    "http://docs.aptlab.net/"))

(define forum-url 
  (if (apt?)
    "https://groups.google.com/forum/#!forum/apt-users"
    "https://groups.google.com/forum/#!forum/cloudlab-users"))

(define tb (lambda () (if (clab?) "CloudLab" "Apt")))

; We want the 'version' to be the date of the most recent commit
(define apt-version
  (with-output-to-string
    (lambda () (system "git show -s --date=short --format='%cd (%h)' HEAD"))))

; Arbitrary width that works reasonably well with the manual class's main
; column width
(define screenshot-width 650)

(define apturl
  (case-lambda
    [() apt-base-url]
    [(page) (string-append apt-base-url page)]))

(define (TODO . what)
  (bold "TODO: " (decode-content what)))

(define nodetype
  (lambda (typename howmany . properties)
          (tabular #:style 'boxed #:sep (hspace 3)
                   (cons
                     (list (bold typename)
                           (string-append (number->string howmany) " nodes"))
                     properties))))

(define (screenshot path)
  (let* ([aptpath (string-append "screenshots/apt/" path)]
         [clabpath (string-append "screenshots/clab/" path)]
         [fullpath (if (apt?)
                     aptpath
                     (if (file-exists? clabpath)
                       clabpath
                       (cdr (cons (displayln (string-append "WARNING: CloudLab missing screenshot " path)) aptpath))))]
         [b (make-object bitmap% fullpath)]
         [width (send b get-width)]
         [scale-factor (* 1.0 (/ screenshot-width width))])
    (list (image #:scale scale-factor fullpath fullpath) (linebreak))))

(define (instructionstep step #:screenshot [screenshot-path #f] . body)
  (item (bold (decode-content (list step)))
        (linebreak)
        (decode-flow body)
        (if screenshot-path
          (screenshot  screenshot-path)
          (void))))

(define (under-construction)
  (bold "This section is under construction"))

(define (future-work tag)
  (margin-note "There are planned features relating to this section: see \""
               (secref tag)
               "\" for more details."))

(define (ssh)
  (tt "ssh"))

(define (code-sample filename)
  (code-inset (verbatim (file->string (string-append "code-samples/" filename)))))