defs.rkt

#lang racket/base
(require scribble/base)
(require scribble/decode)
(require racket/class)
(require racket/draw)
(require racket/system)
(require racket/port)
(require racket/vector)

(provide (all-defined-out))

; Check to see if we are building Apt or CloudLab documentation
(define tb-mode 
  (if (vector-member "cloudlab" (current-command-line-arguments))
    'cloudlab
    'apt))

(define (cl?) (if (equal? tb-mode 'cloudlab) #t #f))

(define apt-base-url
  (if (cl?)
    "https://www.cloudlab.us"
    "https://www.aptlab.net/"))

(define tb (lambda () (if (cl?) "CloudLab" "Apt")))

; We want the 'version' to be the date of the most recent commit
(define apt-version
  (with-output-to-string
    (lambda () (system "git show -s --date=short --format='%cd (%h)' HEAD"))))

; Arbitrary width that works reasonably well with the manual class's main
; column width
(define screenshot-width 650)

(define apturl
  (case-lambda
    [() apt-base-url]
    [(page) (string-append apt-base-url page)]))

(define (TODO . what)
  (bold "TODO: " (decode-content what)))

(define nodetype
  (lambda (typename howmany . properties)
          (tabular #:style 'boxed #:sep (hspace 3)
                   (cons
                     (list (bold typename)
                           (string-append (number->string howmany) " nodes"))
                     properties))))

(define (screenshot path)
  (let* ([fullpath (string-append "screenshots/" path)]
         [b (make-object bitmap% fullpath)]
         [width (send b get-width)]
         [scale-factor (/ screenshot-width width)])
    (list (image #:scale scale-factor fullpath fullpath) (linebreak))))

(define (instructionstep step #:screenshot [screenshot-path #f] . body)
  (item (bold (decode-content (list step)))
        (linebreak)
        (if screenshot-path
          (screenshot  screenshot-path)
          (void))
        (decode-content body)))

(define (under-construction)
  (bold "This section is under construction"))

(define (future-work tag)
  (margin-note "There are planned features relating to this section: see \""
               (secref tag)
               "\" for more details."))

(define (ssh)
  (tt "ssh"))