pruneexpdirs.in 4.78 KB
Newer Older
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230
#!/usr/bin/perl -w
#
# Copyright (c) 2000-2017 University of Utah and the Flux Group.
# 
# {{{EMULAB-LICENSE
# 
# This file is part of the Emulab network testbed software.
# 
# This file is free software: you can redistribute it and/or modify it
# under the terms of the GNU Affero General Public License as published by
# the Free Software Foundation, either version 3 of the License, or (at
# your option) any later version.
# 
# This file is distributed in the hope that it will be useful, but WITHOUT
# ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
# FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Affero General Public
# License for more details.
# 
# You should have received a copy of the GNU Affero General Public License
# along with this file.  If not, see <http://www.gnu.org/licenses/>.
# 
# }}}
#
use English;
use strict;
use Getopt::Std;
use File::Basename;
use Data::Dumper;

#
# Prune dead experiment directories that could not be deleted, typically
# cause files were still open when the experiment was terminated.
#
sub usage()
{
    print("Usage: pruneexpdirs [-n] [-v]\n".
	  "Options:\n".
	  "       -n     Impotent mode, show what would be done.\n".
	  "       -v     Verbose mode.\n");
    exit(-1);
}
my $optlist     = "vn";
my $verbose     = 0;
my $impotent    = 0;
my @deleted     = ();
my @failures    = ();

#
# Configure variables
#
my $TB             = "@prefix@";
my $PROJROOT       = "@PROJROOT_DIR@";
my $GROUPSROOT     = "@GROUPSROOT_DIR@";
my $TBOPS          = "@TBOPSEMAIL@";
my $TBLOGS         = "@TBLOGSEMAIL@";

#
# Untaint the path
#
$ENV{'PATH'} = "$TB/bin:$TB/sbin:/bin:/usr/bin:/usr/bin:/usr/sbin";
delete @ENV{'IFS', 'CDPATH', 'ENV', 'BASH_ENV'};

#
# Turn off line buffering on output
#
$| = 1;

#
# Root only please
#
if ($UID != 0) {
    die("*** $0:\n".
	"    Must run this script as root.\n");
}

#
# Load the Testbed support stuff.
#
use lib "@prefix@/lib";
use libtestbed;

# Protos
sub fatal($);
sub PruneDirs($);
sub ExecQuiet($);

#
# Parse command arguments. Once we return from getopts, all that should be
# left are the required arguments.
#
my %options = ();
if (! getopts($optlist, \%options)) {
    usage();
}
if (defined($options{"v"})) {
    $verbose = 1;
}
if (defined($options{"n"})) {
    $impotent = 1;
    $verbose  = 1;
}
usage()
    if (@ARGV);

# Run this in the project and group directory only!
chdir($PROJROOT) or
    fatal("Could not chdir($PROJROOT)");

# Be paranoid.
my $cmd = "find -E . -maxdepth 3 -type d -mmin +4320 -regex ".
    "'^\\./[^\\/]+/exp/[^\\.]+\\.[0-9]{5}\$' -print";

if ($verbose) {
    print "Running a find in $PROJROOT, patience please ... lots of it.\n";
}
my $dirs = ExecQuiet($cmd);
if ($?) {
    fatal($dirs);
}
if ($dirs ne "") {
    PruneDirs($dirs);
}

#
# Now we do in the groups directory, which requires a different command.
#
chdir($GROUPSROOT) or
    fatal("Could not chdir($GROUPSROOT)");

# Be paranoid.
$cmd = "find -E . -maxdepth 4 -type d -mmin +4320 -regex ".
    "'^\\./[^\\/]+/[^\\/]+/exp/[^\\.]+\\.[0-9]{5}\$' -print";

if ($verbose) {
    print "Running a find in $GROUPSROOT, patience please ... lots of it.\n";
}
$dirs = ExecQuiet($cmd);
if ($?) {
    fatal($dirs);
}
if ($dirs ne "") {
    PruneDirs($dirs);
}
# Always send notification of success to the logs file.
if (@deleted) {
    SENDMAIL($TBLOGS, "pruneexpdirs",
	     "Stale experiment directories deleted:\n\n".
	     join("\n", @deleted), $TBOPS);
}
# Then die if any failures.
if (@failures) {
    fatal("Stale experiment directories could not be deleted:\n\n".
	  join("\n", @failures));
}
exit(0);

#
# Prune a list of directories.
#
sub PruneDirs($)
{
    my ($dirs) = @_;
    
    while ($dirs =~ /^(.*)$/gm) {
	my $line = $1;
	if ($verbose) {
	    if ($impotent) {
		print "Would delete ";
	    }
	    print "$line\n";
	}
	next
	    if ($impotent);

	my $output = ExecQuiet("/bin/rm -rf $line");
    
	if ($?) {
	    push(@failures, "$line\n$output");
	}
	else {
	    push(@deleted, $line);
	}
    }
}

sub fatal($)
{
    my ($mesg) = @_;

    SENDMAIL($TBOPS, "pruneexpdirs failed", $mesg, $TBOPS);
    die("*** $0:\n".
	"    $mesg\n");
}

#
# Run a command, being sure to capture all output. 
#
sub ExecQuiet($)
{
    #
    # Use a pipe read, so that we save away the output
    #
    my ($command) = @_;
    my $output    = "";
    
    #
    # This open implicitly forks a child, which goes on to execute the
    # command. The parent is going to sit in this loop and capture the
    # output of the child. We do this so that we have better control
    # over the descriptors.
    #
    my $pid = open(PIPE, "-|");
    if (!defined($pid)) {
	print STDERR "ExecQuiet Failure; popen failed!\n";
	return -1;
    }
    
    if ($pid) {
	while (<PIPE>) {
	    $output .= $_;
	}
	close(PIPE);
    }
    else {
	open(STDERR, ">&STDOUT");
	exec($command);
    }
    return $output;
}