xmlconvert.in 10.3 KB
Newer Older
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394 395 396 397 398 399 400 401 402 403 404 405 406 407 408 409 410 411 412 413 414 415 416 417 418 419 420 421 422 423 424 425 426 427 428 429 430 431 432 433 434 435 436 437 438 439 440 441 442 443 444 445 446 447 448 449 450 451 452 453 454 455 456 457 458 459 460 461 462 463 464 465 466 467 468 469 470 471 472 473 474 475 476 477 478 479 480 481 482 483 484 485
#!/usr/bin/perl -wT

#
# EMULAB-COPYRIGHT
# Copyright (c) 2000-2003 University of Utah and the Flux Group.
# All rights reserved.
#

use English;
use Getopt::Std;
    
#
# Convert between XML and DB representation of a virtual experiment.
# Very simple, no DTDs, DOMs, XSLs, etc. Just the facts ...
#
sub usage()
{
    print STDOUT "Usage: xmlconvert [-x <xmlfile> [-n]] [-d] pid eid\n";
 
    exit(-1);
}
my $optlist  = "x:vd";
my $fromxml  = 0;
my $nowrite  = 0;
my $debug    = 0;

#
# Configure variables
#
my $TB       = "@prefix@";
my $TBOPS    = "@TBOPSEMAIL@";

# Locals
my $xmlfile;
my $pid;
my $eid;

# This goes at the beginning of the output.
my $XMLHEADER = "<?xml version=\"1.0\" encoding=\"ISO-8859-1\"?>";

#
# These are the virtual tables that make up an experiment.
# Each one could have multiple rows, each of which will be a
# hash table. 
my %virtual_tables = ("experiments"	=> undef,
		      "virt_nodes"	=> undef,
		      "virt_lans"	=> undef,
		      "virt_trafgens"	=> undef,
		      "virt_agents"	=> undef,
		      "virt_routes"	=> undef,
		      "virt_vtypes"	=> undef,
		      "nseconfigs"	=> undef,
		      "eventlist"	=> undef);

# XXX
# The experiment table is special. Only certain fields are allowed to
# be updated. Not sure what the right approach for this is.
#
my %experiment_fields = ("multiplex_factor"	=> 1,
			 forcelinkdelays	=> 1,
			 uselinkdelays		=> 1,
			 usewatunnels		=> 1,
			 uselatestwadata	=> 1,
			 wa_delay_solverweight	=> 1,
			 wa_bw_solverweight	=> 1,
			 wa_plr_solverweight	=> 1);

#
# Turn off line buffering on output
#
$| = 1;

#
# Untaint the path
# 
$ENV{'PATH'} = "/bin:/usr/bin:/sbin:/usr/sbin";
delete @ENV{'IFS', 'CDPATH', 'ENV', 'BASH_ENV'};

#
# Testbed Support libraries
#
use lib "@prefix@/lib";
use libdb;
use libtestbed;

#
# Parse command arguments. Once we return from getopts, all that should
# left are the required arguments.
#
%options = ();
if (! getopts($optlist, \%options)) {
    usage();
}
if (defined($options{"d"})) {
    $debug = 1;
}
if (defined($options{"x"})) {
    $fromxml = 1;
    $xmlfile = $options{"x"};

    if ($xmlfile =~ /^([-\w\/\.]+)$/) {
	$xmlfile = $1;
    }
    else {
	fatal("Bad data in argument: $xmlfile.");
    }
    if (defined($options{"n"})) {
	$nowrite = 1;
    }    
}
if (@ARGV != 2) {
    usage();
}
$pid   = $ARGV[0];
$eid   = $ARGV[1];

# Taint Check.
if ($pid =~ /^([-\w]+)$/) {
    $pid = $1;
}
else {
    fatal("Bad data in argument: $pid.");
}
if ($eid =~ /^([-\w]+)$/) {
    $eid = $1;
}
else {
    fatal("Bad data in argument: $eid.");
}

# Do it
if ($fromxml) {
    readXML($pid, $eid, $xmlfile);
}
else {
    writeXML($pid, $eid);
}
exit(0);

#
# Read in XML and convert to DB representation, doing lots of checks!
# This code is silly. Overly stylized (one tag per line!). Should
# use the XML::Parser package instead. But this was easy and fun for a
# first cut. 
# 
sub readXML($$$) {
    my ($pid, $eid, $xmlfile) = @_;
    my %experiment;
    my $line;
    my $tablename;

    if ($xmlfile ne "-") {
	open(STDIN, "< $xmlfile")
	    or fatal("opening $xmlfile for STDIN: $!");
    }

    #
    # Check the header.
    #
    $line = <STDIN>;
    chomp($line);
    if ($line ne $XMLHEADER) {
	fatal("Improper XML header line: $line");
    }

    #
    # The next line should be the virtual_experiment line, with the
    # pid/eid. We check that, but otherwise ignore the pid/eid.
    #
    $line = <STDIN>;
    if ($line =~ /^<virtual_experiment pid='([-\w]+)' eid='([-\w]+)'>$/) {
	if ($pid ne $1 || $eid ne $2) {
	    fatal("pid/eid mismatch: $line");
	}
    }
    else {
	fatal("Improper virtual_experiment line: $line");
    }

    #
    # Now read in each table, and its rows (which could be more than 1).
    # There can be only one experiments row, of course.
    #
    while (<STDIN>) {
	if ($_ =~ /^\s*<\/virtual_experiment>$/) {
	    last;
	}
	
	# Each loop is a new table.
	if (defined($tablename)) {
	    fatal("Parser out of sync at tablename: $_");
	}
	
	# Table name.
	if ($_ =~ /^\s*<([-\w]+)>/) {
	    $tablename = $1;

	    if (! exists($virtual_tables{$tablename})) {
		fatal("Unknown virtual table: $_");
	    }
	    # New table. Define a list.
	    if (defined($virtual_tables{$tablename})) {
		fatal("Duplicate virtual table: $_");
	    }
	    $virtual_tables{$tablename} = [];
	    print "Starting new table: $tablename\n"
		if ($debug);

	    #
	    # Next is either the table terminator, or the start of a new
	    # row in the current table.
	    #
	    my $row;
	    while (<STDIN>) {
		if ($_ =~ /^\s*(<[-\w\/]+>)$/) {
		    if ($1 eq "</$tablename>") {
			undef($tablename);
			goto newtable;
		    }
		    elsif ($1 eq "<row>") {
			fatal("Parser out of sync at row: $_")
			    if (defined($row));
			print "  Starting new row\n"
			    if ($debug);
			$row = {};
		    }
		    elsif ($1 eq "</row>") {
			fatal("Parser out of sync at /row: $_")
			    if (!defined($row));
			push(@{$virtual_tables{$tablename}}, $row);
			undef($row);
		    }
		}
		elsif ($_ =~ /^\s*\<([-\w]+)\>(.*)\<\/([-\w]+)\>/) {
		    fatal("Parser out of sync at entity: $_")
			if (!defined($row));
		    fatal("Malformed (mismatch) entity: $1/$2/$3")
			if ($1 ne $3);
		    #
		    # Always toss out pid/eid, since we insert our own!
		    #
		    if ($1 ne "pid" && $1 ne "eid") {
			$row->{$1} = xmldecode($2);
			print "    Entering new element: $1/$row->{$1}\n"
			    if ($debug);
		    }
		}
		else {
		    fatal("Malformed entity: $_");
		}
	    }
	}
	else {
	    fatal("Malformed table name: $_");
	}
      newtable:
    }
    #
    # Verify. 
    #
    # Must be exactly one experiments table row, and we prune out lots
    # of stuff that is not allowed. Note that we never insert a new
    # experiment, but only allow updates of certain values. 
    #
    if (scalar(@{$virtual_tables{"experiments"}}) != 1) {
	fatal("Must be exactly one experiments table row!");
    }
    my %experiments_table = %{@{$virtual_tables{"experiments"}}[0]};
    foreach my $key (keys(%experiments_table)) {
	delete($experiments_table{$key})
	    if (!exists($experiment_fields{$key}));
    }

    #
    # Okay, a hokey DoS check. Do not allow more than 10000 total rows!
    # Why so many? Well, Rob likes to generate lots of events!
    #
    my $count = 0;
    foreach my $table (keys(%virtual_tables)) {
	$count += scalar(@{$virtual_tables{$table}})
	    if (defined($virtual_tables{$table}));
    }
    if ($count > 10000) {
	fatal("Too many rows of data!");
    }

    #
    # Okay, thats all the checking we do! There is not much that can
    # screw up the DB, by inserting rows into the allowed set of tables.
    #
    # First the experiments table, which gets an update.
    #
    my @setlist = ();
    foreach my $key (keys(%experiments_table)) {
	$val = $experiments_table{$key};
	if ($val eq "NULL") {
	    push(@setlist, "$key=NULL");
	}
	else {
	    push(@setlist, "$key='$val'");
	}	    
    }
    my $query = "update experiments ".
	        "set " . join(",", @setlist) . " " .
		"where eid='$eid' and pid='$pid'";

    print "$query\n"
	if ($debug);
    DBQueryFatal($query)
	if (!$nowrite);

    #
    # Now all the other tables, which get inserts. Need to delete all the
    # old info too.
    #
    foreach my $table (keys(%virtual_tables)) {
	DBQueryFatal("delete from $table ".
		     "where eid='$eid' and pid='$pid'")
	    if (!$nowrite);
	next
	    if (!defined($virtual_tables{$table}));
	next
	    if ($table eq "experiments");

	foreach my $rowref (@{$virtual_tables{$table}}) {
	    my %rowhash = %{ $rowref };
	    my @fields  = ("pid", "eid");
	    my @values  = ("'$pid'", "'$eid'");

	    foreach my $key (keys(%rowhash)) {
		$val = $rowhash{$key};

		if ($val eq "NULL") {
		    push(@values, "NULL");
		}
		else {
		    push(@values, "'$val'");
		}	    
		push(@fields, $key);
	    }
	    $query = "insert into $table (" . join(",", @fields) . ") ".
		     "values (" . join(",", @values) . ") ";

	    print "$query\n"
		if ($debug);
	    DBQueryFatal($query)
		if (!$nowrite);
	}
    }
    return 0;
}

#
# Convert a virtual experiment representation into XML and spit it out.
# The DB holds the data of course.
#
sub writeXML($$) {
    my ($pid, $eid) = @_;

    my $query_result =
	DBQueryFatal("select * from experiments ".
		     "where eid='$eid' and pid='$pid'");

    if (! $query_result->numrows) {
	fatal("No such experiment $pid/$eid exists!");
    }

    spitxml_header();
    spitxml_opentag("virtual_experiment pid='$pid' eid='$eid'", 0);

    # Spit out all of the tables.
    foreach my $table (keys(%virtual_tables)) {
	spitxml_dbrows($table, 1, 
		       "select * from $table ".
		       "where eid='$eid' and pid='$pid'");
    }
    spitxml_closetag("virtual_experiment", 0);

    return 0;
}

#
# Utility functions to pretty print XML output, with specified indentation.
#
sub spitxml_opentag($$)
{
    my ($tag, $level) = @_;

    my $spaces = $level * 2;

    printf("%${spaces}s<%s>\n", "", $tag);
}

sub spitxml_closetag($$)
{
    my ($tag, $level) = @_;

    my $spaces = $level * 2;

    printf("%${spaces}s</%s>\n", "", $tag);
}

sub spitxml_header()
{
    print "$XMLHEADER\n";
}

sub spitxml_entity($$$)
{
    my ($tag, $data, $level) = @_;
    my $spaces = $level * 2;

    $data = "NULL"
	if (!defined($data));

    printf("%${spaces}s<%s>%s</%s>\n", "", $tag, xmlencode($data), $tag);
}

sub spitxml_dbrow($%)
{
    my($level, %dbrow) = @_;

    spitxml_opentag("row", $level);
    
    foreach my $tag (keys(%dbrow)) {
	my $data = $dbrow{$tag};
	spitxml_entity($tag, $data, $level + 1);

    }
    spitxml_closetag("row", $level);
}

sub spitxml_dbrows($$$)
{
    my($tag, $level, $query) = @_;
    my $query_result = DBQueryFatal($query);
    
    if ($query_result->numrows) {
	spitxml_opentag($tag, $level);
	while (my %hashrow = $query_result->fetchhash()) {
	    spitxml_dbrow($level + 1, %hashrow);
	}
	spitxml_closetag($tag, $level);
    }
}

#
# Convert from/to XML special chars. Not many of them ...
# 
sub xmlencode($)
{
    my ($string) = @_;

    my %specialchars = ('&' => '&amp;',
			'<' => '&lt;',
			'>' => '&gt;',
			"'" => '&apos;',
			'"' => '&quot;');

    $string =~ s/([&<>"'])/$specialchars{$1}/ge;
    return $string;
}

sub xmldecode($)
{
    my ($string) = @_;

    my %specialchars = ('&amp;'  => '&',
			'&lt;'   => '<',
			'&gt;'   => '>',
			'&apos;' => "'",
			'&quot;' => '"');

    $string =~ s/(&\w+;)/$specialchars{$1}/ge;
    return $string;
}

# Die
sub fatal($)
{
    my ($msg) = @_;

    die("*** $0:\n".
	"    $msg\n");
}